LOOKUP 函數（查找和引用函數）

06-18

LOOKUP

適用於: Microsoft Office Excel 2003

從單行或單列區域或者從一個數組（數組:用於建立可生成多個結果或可對在行和列中排列的一組參數進行運算的單個公式。數組區域共用一個公式；數組常量是用作參數的一組常量。）返回值。LOOKUP 函數具有兩種語法形式：

向量LOOKUP 的向量形式在單行區域或單列區域（稱為「向量」）中查找值，然後返回第二個單行區域或單列區域中相同位置的值。

當要查詢的值列表較大或者值可能會隨時間而改變時，使用該向量形式。

數組LOOKUP 的數組形式在數組的第一行或第一列中查找指定的值，然後返回數組的最後一行或最後一列中相同位置的值。

當要查詢的值列表較小或者值在一段時間內保持不變時，使用該數組形式。

注釋對於詳細的測試或七種以上條件的測試，還可以使用 LOOKUP 函數作為 IF 函數的替代函數。請參閱數組形式的示例。

向量形式

向量是只含一行或一列的區域。LOOKUP 的向量形式在單行區域或單列區域（稱為「向量」）中查找值，然後返回第二個單行區域或單列區域中相同位置的值。當要指定的區域包含要匹配的值時，請使用 LOOKUP 函數的這種形式。LOOKUP 的另一種形式自動在第一行或第一列中查找。

LOOKUP(lookup_value,lookup_vector,result_vector)

Lookup_valueLOOKUP 在第一個向量中搜索的值。Lookup_value 可以是數字、文本、邏輯值、名稱或對值的引用。

Lookup_vector只包含一行或一列的區域。lookup_vector 中的值可以是文本、數字或邏輯值。

要點lookup_vector 中的值必須以升序順序放置：...,-2, -1, 0, 1, 2, ...；A-Z；FALSE, TRUE。否則，LOOKUP 可能無法提供正確的值。大寫文本和小寫文本是等同的。

Result_vector只包含一行或一列的區域。它必須與 lookup_vector 大小相同。

評論

如果 LOOKUP 找不到 lookup_value，則它與 lookup_vector 中小於或等於 lookup_value 的最大值匹配。

如果 lookup_value 小於 lookup_vector 中的最小值，則 LOOKUP 會提供 #N/A 錯誤值。

示例

如果將示例複製到一個空白工作表中，示例將更易於理解。

方法

創建一個空白工作簿或工作表。
在「幫助」主題中選擇示例。請不要選擇行或列標題。

從「幫助」中選擇示例

按 Ctrl+C。
在工作表中，選擇單元格 A1，然後按 Ctrl+V。
要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或者在「工具」菜單上，指向「公式審核」，然後單擊「公式審核模式」。

1

2
3
4
5
6

A	B
頻率	顏色
4.14	紅色
4.19	橙色
5.17	黃色
5.77	綠色
6.39	藍色
公式	說明（結果）
=LOOKUP(4.19,A2:A6,B2:B6)	在列 A 中查找 4.19，然後返回列 B 中同一行內的值（橙色）
=LOOKUP(5.00,A2:A6,B2:B6)	在列 A 中查找 5.00，與接近它的最小值 (4.19) 匹配，然後返回列 B 中同一行內的值（橙色）
=LOOKUP(7.66,A2:A6,B2:B6)	在列 A 中查找 7.66，與接近它的最小值 (6.39) 匹配，然後返回列 B 中同一行內的值（藍色）
=LOOKUP(0,A2:A6,B2:B6)	在列 A 中查找 0，並返回錯誤，因為 0 小於 lookup_vector A2:A7 中的最小值 (#N/A)

數組形式

LOOKUP 的數組形式在數組（數組:用於建立可生成多個結果或可對在行和列中排列的一組參數進行運算的單個公式。數組區域共用一個公式；數組常量是用作參數的一組常量。）的第一行或第一列中查找指定的值，並返回數組最後一行或最後一列內同一位置的值。當要匹配的值位於數組的第一行或第一列中時，使用 LOOKUP 的這種形式。當要指定列或行的位置時，使用 LOOKUP 的另一種形式。

提示

一般而言，最好使用 HLOOKUP 或 VLOOKUP 函數而不是 LOOKUP 的數組形式。LOOKUP 的這種形式是為了與其他電子表格程序兼容而提供的。

LOOKUP(lookup_value,array)

Lookup_valueLOOKUP 在數組中搜索的值。Lookup_value 可以是數字、文本、邏輯值、名稱或對值的引用。

如果 LOOKUP 找不到 lookup_value，它會使用數組中小於或等於 lookup_value 的最大值。

如果 lookup_value 小於第一行或第一列中的最小值（取決於數組維度），LOOKUP 會返回 #N/A 錯誤值。

數組包含要與 lookup_value 進行比較的文本、數字或邏輯值的單元格區域。

LOOKUP 的數組形式與 HLOOKUP 和 VLOOKUP 函數非常相似。區別在於：HLOOKUP 在第一行中搜索 lookup_value，VLOOKUP 在第一列中搜索，而 LOOKUP 根據數組維度進行搜索。

如果數組包含寬度比高度大的區域（列數多於行數），LOOKUP 會在第一行中搜索 lookup_value。

如果數組是正方的或者高度大於寬度（行數多於列數），則 LOOKUP 在第一列中進行搜索。

使用 HLOOKUP 和 VLOOKUP，可以通過索引以向下或遍歷的方式搜索，但是 LOOKUP 始終選擇行或列中的最後一個值。

要點數組中的值必須以升序順序放置：...,-2, -1, 0, 1, 2, ...；A-Z；FALSE, TRUE。否則，LOOKUP 無法提供正確的值。大寫文本和小寫文本是等同的。

示例 1

如果將示例複製到一個空白工作表中，示例將更易於理解。

方法

創建一個空白工作簿或工作表。
在「幫助」主題中選擇示例。請不要選擇行或列標題。

從「幫助」中選擇示例

按 Ctrl+C。
在工作表中，選擇單元格 A1，然後按 Ctrl+V。
要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或者在「工具」菜單上，指向「公式審核」，然後單擊「公式審核模式」。

1

A	B
公式	說明（結果）
=LOOKUP("C",{"a","b","c","d";1,2,3,4})	在數組的第一行中查找「C」，查找小於或等於它（「c」）的最大值，然後返回最後一行中同一列內的值 (3)
=LOOKUP("bump",{"a",1;"b",2;"c",3})	在數組的第一行中查找「bump」，查找小於或等於它（「b」）的最大值，然後返回最後一列中同一行內的值 (2)

示例 2

如果將示例複製到一個空白工作表中，示例將更易於理解。

方法

創建一個空白工作簿或工作表。
在「幫助」主題中選擇示例。請不要選擇行或列標題。

從「幫助」中選擇示例

按 Ctrl+C。
在工作表中，選擇單元格 A1，然後按 Ctrl+V。
要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或者在「工具」菜單上，指向「公式審核」，然後單擊「公式審核模式」。

下面的示例使用一個數字數組為測試分數指定字母等級。

1

2
3
4

A
分數
45
90
78
公式	說明（結果）
=LOOKUP(A2,{0,60,70,80,90},{"F","D","C","B","A"})	在數組的第一行中的 A2 (45) 中查找值，查找小於或等於它 (0) 的最大值，然後返回數組最後一行中同一列內的值 (F)
=LOOKUP(A3,{0,60,70,80,90},{"F","D","C","B","A"})	在數組的第一行中的 A3 (90) 中查找值，查找小於或等於它 (90) 的最大值，然後返回數組最後一行中同一列內的值 (A)
=LOOKUP(A4,{0,60,70,80,90},{"F","D","C","B","A"})	在數組的第一行中的 A4 (78) 中查找值，查找小於或等於它 (80) 的最大值，然後返回數組最後一行中同一列內的值 (C)
=LOOKUP(A2,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})	在數組的第一行中的 A2 (45) 中查找值，查找小於或等於它 (60) 的最大值，然後返回數組最後一行中同一列內的值 (F)
=LOOKUP(A3,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})	在數組的第一行中的 A3 (90) 中查找值，查找小於或等於它 (90) 的最大值，然後返回最後一行中同一列內的值 (A-)
=LOOKUP(A4,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})	在數組的第一行中的 A4 (78) 中查找值，查找小於或等於它 (80) 的最大值，然後返回最後一行中同一列內的值 (C+)