office excel最常用函數公式技巧搜集大全(13.12.09更新)10

導讀：截取字元的公式，數據在A1單元格,則公式為:，取數值後三位公式，取數函數，單元格中用函數單獨取出*號前（後）的數，數組公式，用數組公式：，這個用函數可輕易解決：=LEFT(A1,FIND(":",A，若沒有要求一定要用函數解，公式為：=LEFT(A1,FIND("",A1)-1)，採用函數分割：例如：A1:name@163.com，且這個函數沒有四捨五入

至此，讀者一定會發現，再複雜的斜線表頭，利用直線和文本框工具，也就迎刃而解了! ㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜㎜

【字元截取與增減】

截取單元格里某個字元後的字元

=RIGHT(A1,LEN(A1)-SEARCH(",",A1,1))

截取字元的公式

有一組數據101～103*,11～20*?我想截取~至*之間的數字。

=MID($A3,FIND("~",$A3)+1,FIND("*",$A3)-(FIND("~",$A3)+1))

如何確定*號後的數字

=RIGHT(A1,LEN(A1)-FIND("*",A1,1))

=REPLACE(A1,1,FIND("*",A1),)

=TRIM(RIGHT(SUBSTITUTE(A1,"*",REPT(" ",LEN(A1))),LEN(A1)))

=MID(A1,SEARCH("~*",A1)+1,100)

=SUBSTITUTE(A1,LEFT(A1,FIND("*",A1)),"")

｛=--MID(A1,MATCH("~*",MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),)+1,100)｝ =RIGHT(A1,LEN($A$1)-FIND(CHAR(CODE("*")),$A$1,1))（取最後三位）

如何提取數字中間的數

數據在A1單元格,則公式為:

=MID(A1,5,3)

解釋：「5」是從第5位開始提取，「3」是提取3個數。

三個數中,如何取出中間那個

比如1,2,3三個數字,我想取出2,用什麼方法?

=LARGE(A1:A3,2)

取數值後三位公式

=RIGHT(A1,3)

取數函數

單元格中用函數單獨取出 *號前 （後）的數

假如2.01*750位於A1

=MID(A1,1,FIND("*",A1,1)-1) 取得*號前的數據

=MID(A1,FIND("*",A1,1)+1,LEN(A1)-FIND("*",A1,1)+1) 取得*號後的數據

對2.01*750*800的得數就是750*800，而不是800，怎麼辦呢

=MID(B2,FIND("*",B2,FIND("*",B2,1)+1)+1,LEN(B2))

=RIGHT(B2,LEN(B2)-FIND("/",SUBSTITUTE(B2,"*","/",LEN(B2)-LEN(SUBSTITUTE(B2,"*","")))))

如何把單元格中的數字提取出來（字元串中不連續）

數組公式

=SUM(MID(0&A4,LARGE(ISNUMBER(--MID(A4,ROW($1:$20),1))*ROW($1:$20),ROW($1:$20))+1,1)*10^ROW($1:$20)/10)

數字在字元串中不連續如何提取數字

如：3k3mn249up 結果：33249

033k3mn249up 結果：333249

用數組公式：

=SUM(MID(0&A1,LARGE(ISNUMBER(--MID(A1,ROW($1:$1024),1))*

ROW($1:$1024),ROW($1:$308))+1,1)*10^ROW($1:$308)/10)

用如何提取「-」前後的字元

5-0，

4-2，

0-6，

取左邊=CHOOSE(TYPE($D4),MONTH($D4),LEFT($D4,FIND("-",$D4)-1))

取右邊=CHOOSE(TYPE($D4),DAY($D4),RIGHT($D4,LEN($D4)-FIND("-",D$4)))

怎樣刪去﹕後的文字

格式都是 XXXX : YYYYYY,如何只保留XXXX，而全部刪下﹕ 後的文字呢﹖

(XXXX 的長度是不一樣)

這個用函數可輕易解決：=LEFT(A1,FIND(":",A1)-1)

若沒有要求一定要用函數解，那也可以試試用[數據]>（數據剖析）

怎樣只取「.」之後的文字﹖

如：Q24-S4. Working Status 只取 Working Status

如果「.」 前的字數固定

=RIGHT(A1,LEN(A1)-7)

如果不固定

=RIGHT(A1,LEN(A1)-FIND(".",A1))

=TRIM(RIGHT(A1,LEN(A1)-FIND(".",A1,1))

獲取單元格內容中字元串

08:25,18:25

如：要取得單元格b5中的從左邊算起五位的字元串。即是08:25

=LEFT(B5,5)

如：要取得單元格b5中的從右邊算起五位的字元串。即是08:25

=RIGHT(B18,5)

單元格編號，起始位數，從起始位算起的第幾位數

MEP090296

=MID(B1,4,3) 結果：090

如何提取一串數字中的幾位數字（字元）

如：050326

提取後3位數字

=RIGHT(A1,3) 「3」是提取3位，如果改「4」，則提取4位。

=RIGHT(A3,LEN(A3)-3)

=MID(A3,4,3)

=REPLACE(A3,1,3,"")

提取中間的4位數字，「5032」

=MID(A1,2,4)

=MID(A3,(LEN(A3)-4)/2+1,4)

要提取 050324 中的 502 怎麼提取？即：第二、三兩位和第五位數字

=MID(A3,2,2)&MID(A3,5,1)

=MID(A3,2,1)&MID(A3,3,1)&MID(A3,5,1)

如何把一個單元格中的數字挑出來

一個單元格中有數字、空格、漢字，如：「11210101 銀行存款/工行」，數字的位數不確定，但都從最左邊開始，數字和漢字中間有一個空格。如何只把數字顯示出來？

1、如果都是這樣就簡單 "都從最左邊開始，數字和漢字中間有一個空格"

假定在A1，公式為：=LEFT(A1,FIND(" ",A1)-1)

2、數據分列不更簡單么？分列符號選中空格前面那個框。

分割文本

有一列數據，全部是郵箱的，現在想將@前面的賬號與@後面的域名分割開，分為兩列，如何做？

採用函數分割：例如：A1: name@163.com

B1:=LEFT(A1,FIND("@",A1)-1) --> name

C1:=RIGHT(A1,LEN(A1)-FIND("@",A1)) --> 163.com

或：數據-分列-分列-分隔符號-@就可以了

按照給定的位數，截斷小數點後的數字

對整數無效，且這個函數沒有四捨五入的功能

12512.2514 12512.25

=TRUNC(B23,2)

單元格數字提取問題

單元格裡面填寫的 CHIP(0601-2299),把0601-2299 提取出來應該怎麼做。

=IF(B3="","",SUBSTITUTE(MID(B3,FIND("(",B3)+1,100),")",""))

我用IF函數是因為看到你給的表格當中,數據和數據之間都有一行空行,

如果沒有空行的話,數據是連續的時候公式可以簡化為：

=SUBSTITUTE(MID(B3,FIND("(",B3)+1,100),")","")

以關鍵字提取名稱

=INDIRECT("A"&MATCH(D2,B:B,))

=VLOOKUP(D2,IF({1,0},$B$2:$B$23,$A$2:$A$23),2,0)

如何把文本中的前幾個字元去除

如將「第二班AAA」中的「第二班」三個字去除。

1、用公式：

=RIGHT($A2,3)

=RIGHT($A2,LEN($A2)-FIND("班",$A2))

=MID($A2,FIND("班",$A2)+1,LEN($A2))

=RIGHT(B2,LENB(B2)-LEN(B2))

=REPLACE(A1,1,3,"")

=SUBSTITUTE(A1,"第二班",)

如前幾個字元或後英文字數, 不相同或不固定，公式可用:

{=MID(A2,MATCH(0,--(CODE(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1))<65),0),255)}

2、數據>分列>固定寬度,把上述數據分為兩列後,刪除第一班的列

對一列中的文字統一去掉最後一個字

能否對一列中的文字統一去掉最後一個字?這些文字不統一,有些字數多,有些字數少。如何處理?

=REPLACE(A1,LEN(A1),1," ")(在過渡列進行)

討如何去掉單元格中的第一個數字？

=MID(A1,2,LEN(A1)-1) 或者 =RIGHT(A1,LEN(A1)-1)

=REPLACE(A1,1,1,"")

論一下取最後一個單詞的方法

例如現在在A1中有一句「M. Henry Jackey」，如何用函數將最後的一個單詞取出來呢？ 當然，我們現在是知道最後的單詞是6個字元，可以用Right(A1,6)來計算，但如果最後一個單詞的字元數是不定的呢，如果做呢？ 請大家試下有幾種方法。