Excel學習筆記 用公式進行多條件求和
多條件求和在實際的工作中應用非常廣泛，我們可以用公式來實現多條件求和，
用到的函數有SUM、SUMPRODUCT、MMULT和SUMIFS， 其中SUMIFS函數是Excel2007新增的函數。下面來是一個具體的例子，數據在A2:F23區域中，其中要求和的區域是F2：F23。
方法一：用SUM函數
用SUM函數進行多條件求和，公式基本結構是SUM((條件1)*(條件2)*(求和數據區))，
必需用數組公式，公式輸入完畢後按Ctrl+Alt+Enter結束。1.計算出7月份廣州的總銷量：
=SUM(($A$2:$A$23="7月")*($B$2:$B$23="廣州")*$F$2:$F$23)
2.計算出7月和10月拖鞋總銷量：
=SUM((($A$2:$A$23="7月")+($A$2:$A$23="10月"))*($C$2:$C$23="拖鞋")*$F$2:$F$23)
公式中的加號相當於邏輯或。
3.計算出7-10月武漢男式襪子銷量：
=SUM((($B$2:$B$23="武漢")*($C$2:$C$23="襪子"))*($E$2:$E$23="男")*$F$2:$F$23)
方法二：用SUMPRODUCT函數
公式結構同SUM函數，只不過不用數組公式。
1.計算出7月份廣州的總銷量：
=SUMPRODUCT(($A$2:$A$23="7月")*($B$2:$B$23="廣州")*$F$2:$F$23)
2.計算出7月和10月拖鞋總銷量：
=SUMPRODUCT((($A$2:$A$23="7月")+($A$2:$A$23="10月"))*($C$2:$C$23="拖鞋")*$F$2:$F$23)
公式中的加號相當於邏輯或。
3.計算出7-10月武漢男式襪子銷量：
=SUMPRODUCT((($B$2:$B$23="武漢")*($C$2:$C$23="襪子"))*($E$2:$E$23="男")*$F$2:$F$23)
方法三：用MMULT函數
用MMULT函數進行多條件求和特別適合於數據量較大的情況。
MMULT函數的語法是：MMULT(array1,array2)， 其中參數array1和array2 是要進行矩陣乘法運算的兩個數組。 函數返回兩個數組的矩陣乘積。要求array1 的列數必須與 array2 的行數相同， 而且兩個數組中都只能包含數值。本例中的第一參數為一行N列，而第二參數為N行一列。公式的基本結構是MMULT(條件1，(條件2)*(求和數據區))，
必需用數組公式，公式輸入完畢後按Ctrl+Alt+Enter結束。1.計算出7月份廣州的總銷量：
=MMULT(--(TRANSPOSE($A$2:$A$23)="7月"),($B$2:$B$23="廣州")*$F$2:$F$23)
公式中雙重否定符「--」將其後面的結果變成數值。2.計算出7月和10月拖鞋總銷量：
=MMULT(--(TRANSPOSE(($A$2:$A$23="7月")+($A$2:$A$23="10月"))),($C$2:$C$23="拖鞋")*$F$2:$F$23)
公式中的加號相當於邏輯或。
3.計算出7-10月武漢男式襪子銷量：
=MMULT(--(TRANSPOSE(($B$2:$B$23="武漢")*($C$2:$C$23="襪子"))),($E$2:$E$23="男")*$F$2:$F$23)
方法四：用SUMIFS函數
SUMIFS函數是Excel 2007中的新增函數，用它進行多條件求和非常方便。其語法是：
SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …),即：
SUMIFS(求和區域,條件區域1，條件1，[條件區域2，條件2]，…) 1.計算出7月份廣州的總銷量：=SUMIFS($F$2:$F$23,$A$2:$A$23,"7月",$B$2:$B$23,"廣州")
2.計算出7月和10月拖鞋總銷量：
=SUMIFS($F$2:$F$23,$A$2:$A$23,"7月",$C$2:$C$23,"拖鞋")+SUMIFS($F$2:$F$23,$A$2:$A$23,"10月",$C$2:$C$23,"拖鞋")
3.計算出7-10月武漢男式襪子銷量：
=SUMIFS($F$2:$F$23,$B$2:$B$23,"武漢",$C$2:$C$23,"襪子",$E$2:$E$23,"男")
| 月份 | 城市 | 商品 | 規格 | 類別 | 銷售數量 |
| 7月 | 廣州 | 襪子 | 單色 | 男 | 359 |
| 7月 | 武漢 | 襪子 | 黑色男 | 男 | 535 |
| 7月 | 青島 | 帽子 | 帶邊 | 女 | 890 |
| 7月 | 廣州 | 拖鞋 | 帶跟紅色 | 女 | 605 |
| 7月 | 青島 | 拖鞋 | 帶跟黑色 | 男 | 331 |
| 8月 | 廣州 | 襪子 | 單色 | 男 | 297 |
| 8月 | 青島 | 襪子 | 紅色女 | 女 | 705 |
| 8月 | 武漢 | 襪子 | 黑色男 | 男 | 308 |
| 8月 | 青島 | 帽子 | 帶邊 | 女 | 995 |
| 8月 | 武漢 | 帽子 | 針織 | 女 | 960 |
| 8月 | 廣州 | 拖鞋 | 帶跟紅色 | 女 | 360 |
| 9月 | 廣州 | 襪子 | 單色 | 男 | 1021 |
| 9月 | 青島 | 襪子 | 紅色女 | 女 | 547 |
| 9月 | 廣州 | 襪子 | 黃色女 | 女 | 658 |
| 9月 | 青島 | 帽子 | 帶邊 | 女 | 319 |
| 9月 | 廣州 | 拖鞋 | 帶跟紅色 | 女 | 884 |
四種計算方法與12個公式計算結果：
| 方法一：用SUM函數 | |
| 1.計算出7月份廣州的總銷量： | 964 |
| 2.計算出7月和10月拖鞋總銷量： | 936 |
| 3.計算出7-10月武漢男式襪子銷量： | 843 |
| 方法二：用SUMPRODUCT函數 | |
| 1.計算出7月份廣州的總銷量： | 964 |
| 2.計算出7月和10月拖鞋總銷量： | 936 |
| 3.計算出7-10月武漢男式襪子銷量： | 843 |
| 方法三：用MMULT函數 | |
| 1.計算出7月份廣州的總銷量： | 964 |
| 2.計算出7月和10月拖鞋總銷量： | 936 |
| 3.計算出7-10月武漢男式襪子銷量： | 843 |
| 方法四：用SUMIFS函數 | |
| 1.計算出7月份廣州的總銷量： | 964 |
| 2.計算出7月和10月拖鞋總銷量： | 936 |
| 3.計算出7-10月武漢男式襪子銷量： | 843 |
推薦閱讀：